// 開いている2つのファイルを画面に合わせて左右に並べて表示
// Inkscapeキャンバスウィンドウ以外は無視します。
// ウィンドウの高さは画面サイズ高さを自動取得します(タスクバーを無視)
// 
// ウィンドウの幅は画面サイズ幅÷2にリサイズされます。
// 配置は、実行した時点で前面にあったウィンドウを左に、背面にあった
// ウィンドウを右に表示します(3つ以上開いている時は開いた順で次のウィンドウ)。
// タスクバーを画面上にしていると、Windowsの設定によってはタイトルバー
// がタスクバーの下に潜り込んでしまいます。
// タスクバーを自動で隠す設定にするか、ウィンドウ下を掴んで高さをリサイズ
// →[Alt+Space]→[M]→[↓長押し]→[Enter]でタスクバーに隠れた部分が出てきます。
// タスクバーを画面下でステータスバーが見えなくなる場合も同様になります
// 
// 元のウィンドウサイズに戻す場合はUWSCフォルダのRecover_Win_Size.uwsを実行して下さい。

TOPWINid=GETID(" - Inkscape","gdkWindowToplevel",0.1)
While TOPWINid<0
  MsgBox("Inkscapeが起動してません")
  Exit
Wend

CtrlWin(TOPWINid,ACTIVATE)
stt="<#DBL>"+GetStr(TOPWINid,0,1)+"<#DBL>"
SCKEY(TOPWINid,VK_CTRL,VK_TAB)
KBD(VK_CTRL,2,40)
Sleep(0.3)
NEXTWINid=GETID(GET_ACTIVE_WIN)
nextwin="<#DBL>"+GetStr(NEXTWINid,0,1)+"<#DBL>"

While nextwin=stt
  MsgBox("Inkscapeのキャンバスが1つです")
  Exit
Wend

LockHard(True)
CtrlWin(TOPWINid,ACTIVATE)

stx=STATUS(TOPWINid,ST_X)
sty=STATUS(TOPWINid,ST_Y)
stw=STATUS(TOPWINid,ST_WIDTH)
sth=STATUS(TOPWINid,ST_HEIGHT)
wks1="ACW(GETID("+stt+"),"+stx+","+sty+","+stw+","+sth+",200)"

RECOVRid=FOPEN("Recover_Win_Size.uws",F_write)
FPUT(RECOVRid,wks1) 
FCLOSE(RECOVRid) 
Sleep(0.2)

ACW(TOPWINid,0,0,G_SCREEN_W/2,G_SCREEN_H,200)
Sleep(0.2)
SCKEY(TOPWINid,VK_5)
SCKEY(TOPWINid,VK_CTRL,VK_TAB)
KBD(VK_CTRL,2,40)
Sleep(0.5)

stx2=STATUS(NEXTWINid,ST_X)
sty2=STATUS(NEXTWINid,ST_Y)
stw2=STATUS(NEXTWINid,ST_WIDTH)
sth2=STATUS(NEXTWINid,ST_HEIGHT)
wks2="ACW(GETID("+nextwin+"),"+stx2+","+sty2+","+stw2+","+sth2+",200)"

RECOVERid=FOPEN("Recover_Win_Size.uws",F_read or F_write)
FPUT(RECOVERid,wks2,0) 
FCLOSE(RECOVERid) 
Sleep(0.2)

ACW(NEXTWINid,G_SCREEN_W/2,0,G_SCREEN_W/2,G_SCREEN_H,200)
Sleep(0.5)
SCKEY(NEXTWINid,VK_5)
CtrlWin(TOPWINid,ACTIVATE)
SCKEY(TOPWINid,VK_SHIFT,VK_CTRL,L)
KBD(VK_SHIFT,2,40)
KBD(VK_CTRL,2,40)
Sleep(0.2)
Layers=GETID("レイヤー(S) (Shift+Ctrl+L)","gdkWindowToplevel",-1)
//Layers=GETID("Layers (SHIFT+CTRL+L)","gdkWindowToplevel",-1)
CtrlWin(Layers,TOPMOST)
CtrlWin(TOPWINid,ACTIVATE)
LockHard(False)